Conversion PDF to Jpeg

@echo off
rem 1130
set w=1200
set h=1600

cls
setlocal ENABLEDELAYEDEXPANSION
for %%i in ("file 1.pdf" "file2.pdf") do (
set filename=%%i
call pdf2jpg !filename! %w% %h%
)

:end
@echo on

@echo off
set from=%1
set w=%2
set h=%3

rem /*
rem links:
rem http://www.ghostscript.com/doc/current/Use.htm
rem http://www.dostips.com/DtTipsStringManipulation.php
rem http://stackoverflow.com/questions/12675371/how-to-set-custom-page-size-with-ghostscript
rem http://stackoverflow.com/questions/3880342/how-to-extract-the-size-of-pdf-dimensions-not-file-size
rem */

:cls
rem // remove surrounding quotes
for /f "useback tokens=*" %%a in ('%from%') do set from=%%~a

set dir=%from:.pdf=%

set papersize=a4
set geometry=%w%x%h%
set first=1
set last=10
set resolution=300
set n=4
set quality=100
set device=jpeg
set ext=jpg
rem // set device=pngalpha
rem // set ext=png

rem //
set quiet=-q
set _range=-dFirstPage=%first% -dLastPage=%last%
rem // set _resolution=-r%resolution%
set _quality=-dJPEGQ=%quality%
set _device=-sDEVICE=%device%
rem // set _papersize=-sPAPERSIZE=%papersize% -dPDFFitPage
rem //
set _geometry=-g%geometry% -dPDFFitPage

set cmd=gs %quiet% -dBATCH -dNOPAUSE -sOutputFile="%dir%\%%0%n%d.%ext%" %_resolution% %_geometry% %_papersize% %_quality% %_device% %_range% "%from%"

echo.
echo -- PDF to jpeg converter
echo.
echo source: %from%
echo Extract to : %dir%\%%0%n%d.jpg
echo.
:echo
if not exist "%dir%" md "%dir%"
echo %cmd%
echo.
%cmd%
echo.
echo job done.

:end
set from=
set device=
set resolution=
set n=
set ext=
set w=
set h=
set cmd=
@echo on